A Host Scanner for STCP

& scan starts here
&
& Version 0.00 09-02-24
& Version 0.10 10-11-26  Added disclaimer
& noah.davids@stratus.com
&
& The latest version of this macro and documentation can be found at
&    http://noahdavids.org/self_published/host_scanner_for_STCP.html                     
&
& This software is provided on an "AS IS" basis, WITHOUT ANY WARRANTY OR ANY
& SUPPORT OF ANY KIND. The AUTHOR SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTIES
& OF MERCHANTABILITY OR FITNESS FOR ANY PARTICULAR PURPOSE.  This disclaimer
& applies, despite any verbal representations of any kind provided by the
& author or anyone else.
&
&
&begin_parameters
START_IP starting_ip_address:string,req
END_IP ending_ip_address:string,req
&end_parameters
&
&
& make sure extraneous stuff isn't echoed into the results file
&if (process_type) = 'batch' &then &do
set_ready -format off
&echo no_command_lines
&end
&        
&
& because I always redisplay the arguments
display_line scan &START_IP& &END_IP&
&
&
& parse the dotted decimal IP address into an integer
&set_string X &START_IP&
&set L (index &X& '.')
&set_string X1 (substr &X& 1 (calc &L& - 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set START &X1&
&set_string X (substr &X& (calc &L& + 1))
&if (length A&X&) = 1 &then &goto MISSING_OCTET
&set L (index &X& '.')
&set_string X1 (substr &X& 1 (calc &L& - 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set START (calc (calc &START& * 256) + &X1&)
&set_string X (substr &X& (calc &L& + 1))
&if (length A&X&) = 1 &then &goto MISSING_OCTET
&set L (index &X& '.')
&set_string X1 (substr &X& 1 (calc &L& - 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set START (calc (calc &START& * 256) + &X1&)
&set_string X1 (substr &X& (calc &L& + 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set START (calc (calc &START& * 256) + &X1&)
&
&set_string X &END_IP&
&set L (index &X& '.')
&set_string X1 (substr &X& 1 (calc &L& - 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set END &X1&
&set_string X (substr &X& (calc &L& + 1))
&if (length A&X&) = 1 &then &goto MISSING_OCTET
&set L (index &X& '.')
&set_string X1 (substr &X& 1 (calc &L& - 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set END (calc (calc &END& * 256) + &X1&)
&set_string X (substr &X& (calc &L& + 1))
&if (length A&X&) = 1 &then &goto MISSING_OCTET
&set L (index &X& '.')
&set_string X1 (substr &X& 1 (calc &L& - 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set END (calc (calc &END& * 256) + &X1&)
&set_string X1 (substr &X& (calc &L& + 1))
&if (length A&X1&) = 1 &then &goto MISSING_OCTET
&if &X1& > 255 &then &goto OCTET_ERROR
&set END (calc (calc &END& * 256) + &X1&)
&
&
& set up the output file
&set_string DATE_TIME_STAMP (date).(time)
attach_default_output (process_dir)>scan_results
display_line Scanning &START_IP& - &END_IP& on &DATE_TIME_STAMP&
display_line
display_line
detach_default_output
&
&
& loop through the IP addresses
&set X &START&
&while &X& <= &END&
&
& The commands will not an decimal integer value but they will take a
& hexadecimal value.
&set_string H (hexadecimal &X&)
&
& If the decimal value is too large the hexadecimal command function will
& place a leading 0 in the string so there are 9 hexits instead of 8. There
& is also a trailing "x" so a large value will end up as a 10 character
& string instead of 9. The leading 0 must be removed so that subsequent
& processing can deal with 2 hexits at a time.
&if (length &H&) = 10 &then &set_string H (substr &H& 2)
&
& If the decimal value is too small the hexadecimal command function will
& not place a leading 0 in string so there are only 7 hexits instead of 8. The
& trailing "x" makes the string 8 characters instead of 9. A leading 0 needs
& to be added.
&if (length &H&) = 8 &then &set_string H 0&H&
&
& remove the training "x"
&set_string H (rtrim &H& 'x')
&
& ping the IP address, not that the ping command adds "0x" to the hex string
attach_default_output (process_dir)>foo
ping 0x&H& -count 1 -timeout 2
detach_default_output
&
& We don't care what the result of the ping command was so we can reuse the
& output file for the arp command output. Note again the added "0x"
attach_default_output (process_dir)>foo
arp 0x&H&
detach_default_output
&
&
& convert the hex string back to dotted decimal notation. This is why I
& wanted the hex string to be 8 hexits long.
&set_string IP1 (substr &H& 1 2)
&set_string IP2 (substr &H& 3 2)
&set_string IP3 (substr &H& 5 2)
&set_string IP4 (substr &H& 7 2)
&set_string CURRENT (calc 0&IP1&x).(calc 0&IP2&x).(calc 0&IP3&x).(calc 0&IP4&x)
&
&
& Build the output file but looking for the dotted decimal IP address in the
& ARP table output
attach_default_output (process_dir)>scan_results -append
display (process_dir)>foo -match &CURRENT& -no_header
detach_default_output
&
&
& Add 1 to the decimal interger to process the next IP address
&set X (calc &X& + 1)
&end
&
&
& End of the loop, copy the output file from the process dir to the current
& dir and give it the correct name. Also display it.
copy_file (process_dir)>scan_results scan_results.&DATE_TIME_STAMP&
display scan_results.&DATE_TIME_STAMP&
&
&
& Done with the macro
&return
&
&
& Go here if one of the octets specified in the initial arguments was not
& valid.
&label OCTET_ERROR
display_line &X1& is not a valid IP octet
&return  
&
&
&label MISSING_OCTET
display_line One of the IP addresses &START_IP& or &END_IP&
display_line does not contain all 4 octets
&
&
& scan stops here